New SpinCAD Designer release with major usability improvements

A comment about the new Faust Compressors. I had been looking at this article at the Spin Knowledge Base:

Spin Semiconductor - Programming the FV-1

Spin Semiconductor designs and markets specialized mixed signal integrated circuits for the consumer music and audio industries
spinsemi.com spinsemi.com

I pointed Claude at this and said "make a block and show me its response". It was nothing like what you'd expect from a compressor. The notes talk about the controls being "interactive" - like when you adjust your monitor's red, the blue changes also and when you adjust blue, green changes too. This is a recipe for frustration and after 4 hours I knocked it on the head and pointed it at a couple of Faust compressors and said "how about these" which it did perfectly on the first try. The tradeoff is that they take around half of the available instructions.

This made me realize how unique the FV-1 really is - it does some things really well, others not so much but kinda sorta. Given how much of my life I've devoted to it, it's hard for me to say bad things about it.
 
DL - what are the "S/O Clamp Tri", "S/O Clamp Sine", "S/O Range Tri" & "S/O Range Sine" blocks in the 'phaser-modulation-test.spcdj' patch? I seem unable to find them on the menu in the 1069 release. Are those just part of a special test?
 
A feature question:

Is it possible to integrate a simple Delay again ?

Sure it''s good to ave some very tricky delay modules, but I think for beginners (like me)
things would be easier if there were basic/tutorialType modules in each applicable categorie ..

Best regards
 
Cybercow said:
DL - what are the "S/O Clamp Tri", "S/O Clamp Sine", "S/O Range Tri" & "S/O Range Sine" blocks in the 'phaser-modulation-test.spcdj' patch? I seem unable to find them on the menu in the 1069 release. Are those just part of a special test?
Click to expand...
That was a patch that Claude created and he managed to give the blocks individual names, which is not generally possible directly in the program. S/O just means scale offset.

HarryR said:
A feature question:

Is it possible to integrate a simple Delay again ?

Sure it''s good to ave some very tricky delay modules, but I think for beginners (like me)
things would be easier if there were basic/tutorialType modules in each applicable categorie ..

Best regards
Click to expand...
Well, OK, in the meantime, there's the three-tap delay that I use even when I only need one delay. If I implement a single delay it's going to be that with the other two taps and control inputs missing.

Thx!

DL
 
Wow! All these changes and additions are definitely pumping new life into SpinCAD Designer. Loving the new features. So much more to explore, learn and play with.
 
I am trying to resist the urge to add more blocks in favor of documentation and actually trying out some of these new ones to make them usable. Please keep the comments coming, even if you are confused about something.

Thx,

DL
 
Sure thing DL. For one, can't get the Ambience block to produce an ambient-like effect. Sounds more like tiny tank. Do you have an example?
 
Cybercow said:
Sure thing DL. For one, can't get the Ambience block to produce an ambient-like effect. Sounds more like tiny tank. Do you have an example?
Click to expand...
Hello Cybercow,

This is a wrap of the Spin P16_V_Ambience_9_10.spn program which came from somewhere on their website but as I cannot figure out where, am just pasting it here. It's early reflections and I agree it doesn't sound like much. I'll take a look sometime to make sure I didn't screw it up somehow. Thanks!

OK I think I figured it out. This is one of those programs that uses a Pot to essentially switch between two settings, in other words, they're expecting you to connect a switch rather than a pot. By hooking up the time and tone controls and turning them both all the way up I get the barest hint of "early reflections". If you were expecting Chords of Orion ambience, that ain't happening here.

DL

;P16_V_Ambience, bright and dark, programs 9 and 10

;based on a mulitapped delay with exponential decay control, littered with AP filters

;memory declarations:

mem del 17000

mem ap 31
mem ap1 54
mem ap2 96
mem ap3 142
mem ap4 189

;declare register equates:

equ krt reg0
equ lf1 reg1
equ lf2 reg2
equ lf3 reg3
equ lf4 reg4
equ temp reg5

;declare constants:

equ kfl 0.3
equ kap 0.6

;clear read-first registers:

skp run,endclr
wrax lf1,0
wrax lf2,0
wrax lf3,0
wrax lf4,0
endclr:

;prepare krt:

rdax pot1,1
log 0.3,0
exp 0.3,0.5 ;ranges 0.5 to 0.8
wrax krt,0

;get inputs into delay, with an AP:

rdax adcl,0.25
rdax adcr,0.25
rda ap#,kap
wrap ap,-kap
wra del,0

;now install APs and filters into delay:

rda del+600,1
rda ap1#,kap
wrap ap1,-kap
wrax temp,-1
rdfx lf1,kfl
wrhx lf1,-1
mulx pot0
rdax temp,1
wra del+600,0

rda del+1000,-1
rda ap2#,-kap
wrap ap2,kap
wrax temp,-1
rdfx lf2,kfl
wrhx lf2,-1
mulx pot0
rdax temp,1
wra del+1000,0

rda del+1641,1
rda ap3#,kap
wrap ap3,-kap
wrax temp,-1
rdfx lf3,kfl
wrhx lf3,-1
mulx pot0
rdax temp,1
wra del+1641,0

rda del+2456,-1
rda ap4#,-kap
wrap ap4,kap
wrax temp,-1
rdfx lf4,kfl
wrhx lf4,-1
mulx pot0
rdax temp,1
wra del+2456,0

;now derive each output as a set of taps, exponentially varying in amplitude.
;space allows for 19 taps on each side. Remember, the Haas effect is at about 1000
;samples.

rda del+5500,1
mulx krt
rda del+5121,1
mulx krt
rda del+4912,1
mulx krt
rda del+4474,1
mulx krt
rda del+4267,1
mulx krt
rda del+3914,1
mulx krt
rda del+3587,1
mulx krt
rda del+3265,1
mulx krt
rda del+2954,1
mulx krt
rda del+2532,1
mulx krt
rda del+2262,1
mulx krt
rda del+1994,1
mulx krt
rda del+1712,1
mulx krt
rda del+1475,1
mulx krt
rda del+1159,1
mulx krt
rda del+746,1
mulx krt
rda del+652,1
mulx krt
rda del+351,1
mulx krt
rda del+187,1
sof 1.999,0
wrax dacl,0

rda del+5520,1
mulx krt
rda del+5129,1
mulx krt
rda del+4908,1
mulx krt
rda del+4460,1
mulx krt
rda del+4269,1
mulx krt
rda del+3914,1
mulx krt
rda del+3583,1
mulx krt
rda del+3265,1
mulx krt
rda del+2957,1
mulx krt
rda del+2522,1
mulx krt
rda del+2262,1
mulx krt
rda del+1999,1
mulx krt
rda del+1712,1
mulx krt
rda del+1473,1
mulx krt
rda del+1159,1
mulx krt
rda del+747,1
mulx krt
rda del+656,1
mulx krt
rda del+348,1
mulx krt
rda del+187,1
sof 1.999,0
wrax dacr,0
Click to expand...
 
Last edited:
You must log in or register to reply here.
Back
Top